<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
	
	<mx:Script>
		<![CDATA[
			import mx.events.DynamicEvent;
			import mx.events.FlexEvent;
			import mx.core.IUIComponent;
			import mx.managers.SystemManager;
			
			private var _systemManager:SystemManager;
			private var _innerApplication:Object;
			
			private function completeHandler(event:Event):void 
			{
				_systemManager = SystemManager(video1.content);
				_systemManager.addEventListener(FlexEvent.APPLICATION_COMPLETE, applicationCompleteHandler);
				_systemManager.addEventListener(FlexEvent.UPDATE_COMPLETE, applicationCompleteHandler);
			}
			
			private function applicationCompleteHandler(event:Event):void 
			{
				_innerApplication = _systemManager.application;
				_innerApplication.addEventListener("onPropertyChange", propertyChangeHandler);
				_innerApplication.addEventListener("onCreationComplete", creationCompleteHandler);
				_innerApplication.addEventListener("onCallback", callbackHandler);
				_innerApplication.setProperty("controls", true);
				_innerApplication.setProperty("live", true);
			}
			
			private function propertyChangeHandler(event:DynamicEvent):void
			{
				// event has property, oldValue, newValue
				trace("onPropertyChange: " + event.property + " " + event.oldValue + "=>" + event.newValue);
			}
			
			private function creationCompleteHandler(event:Event):void
			{
				// event has nothing
				trace("onCreationComplete");
			}
			
			private function callbackHandler(event:DynamicEvent):void
			{
				// event has method, args
				trace("onCallback: " + event.method + " " + event.args);
			}
		]]>
	</mx:Script>
	
	<mx:SWFLoader id="video1" source="VideoIO.swf" width="320" height="240" init="completeHandler(event)"/>
	
</mx:Application>